Új MT4 build bejelentve – 900

//+------------------------------------------------------------------+
//|                                                    TemplTest.mq5 |
//|                        Copyright 2015, MetaQuotes Software Corp. |
//|                                             https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2015, MetaQuotes Software Corp."
#property link      "https://www.mql5.com"
#property version   "1.00"
//+------------------------------------------------------------------+
//| Declare a template class                                         |
//+------------------------------------------------------------------+
template<typename T>
class TArray
  {
protected:
   T                 m_data[];
 
public:
 
   bool              Append(T item)
     {
      int new_size=ArraySize(m_data)+1;
      int reserve =(new_size/2+15)&~15;
      //---
      if(ArrayResize(m_data,new_size,reserve)!=new_size)
         return(false);
      //---
      m_data[new_size-1]=item;
      return(true);
     }
   T                 operator[](int index)
     {
      static T invalid_index;
      //---
      if(index<0 || index>=ArraySize(m_data))
         return(invalid_index);
      //---
      return(m_data[index]);
     }   
  };
//+------------------------------------------------------------------+
//| Template class of a pointer array. In the destructor, it deletes |
//| the objects, the pointers to which were stored in the array.     |
//|                                                                  |
//| Please note the inheritance from the TArray template class       |
//+------------------------------------------------------------------+
template<typename T>
class TArrayPtr : public TArray<T *>
  {
public:
   void             ~TArrayPtr()
     {
      for(int n=0,count=ArraySize(m_data);n<count;n++)
         if(CheckPointer(m_data[n])==POINTER_DYNAMIC)
            delete m_data[n];
     }
  };
//+------------------------------------------------------------------------+
//| Declare the class. Pointers to its objects will be stored in the array |
//+------------------------------------------------------------------------+
class CFoo
  {
   int               m_x;
public:
                     CFoo(int x):m_x(x) { }
   int               X(void) const { return(m_x); }
  };
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
TArray<int>     ExtIntArray;   // instantiate TArray template (specialize TArray template by the int type)
TArray<double>  ExtDblArray;   // instantiate TArray template (specialize TArray template by the double type)
TArrayPtr<CFoo> ExtPtrArray;   // instantiate TArrayPtr template (specialize TArrayPtr template by the CFoo type)
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- fill arrays with data
   for(int i=0;i<10;i++)
     {
      int integer=i+10;
      ExtIntArray.Append(integer);
 
      double dbl=i+20.0;
      ExtDblArray.Append(dbl);
 
      CFoo *ptr=new CFoo(i+30);
      ExtPtrArray.Append(ptr);
     }
//--- output the array contents
   string str="Int:";
   for(i=0;i<10;i++)
      str+=" "+(string)ExtIntArray[i];      
   Print(str);   
   str="Dbl:";
   for(i=0;i<10;i++)
      str+=" "+DoubleToString(ExtDblArray[i],1);
   Print(str);   
   str="Ptr:";
   for(i=0;i<10;i++)
      str+=" "+(string)ExtPtrArray[i].X();      
   Print(str);
//--- CFoo objects created via new should not be deleted, since they are deleted in the TArrayPtr<CFoo> object destructor  
  }